PrintJob.start()

Доступность

Flash Player 7.

Синтаксис

my_pj.start() : Boolean

Параметры

Нет.

Возвращает

Булева величина: true, если пользователь выбрал OK в диалоговом окне Print; false, если пользователь выбрал Cancel или произошла ошибка.

Описание

Метод; отображает диалог Print и запускает спулер (программу-планировщик печати). Диалоговое окно позволяет пользователю изменять настройки. Когда метод PrintJob.start() возвращает true, создаются следующие свойства, представлющие настройки, выбранные пользователем:

Свойство	Тип данных	Единицы измерения	Описание
`PrintJob.paperHeight`	Number	Пункты	Общая высота бумаги.
`PrintJob.paperWidth`	Number	Пункты	Общая ширина бумаги .
`PrintJob.pageHeight`	Number	Пункты	Высота печатной области; отступы игнорируются.
`PrintJob.pageWidth`	Number	Пункты	Ширина печатной области; отступы игнорируются.
`PrintJob.orientation`	String	N/A	Ориентация, “Portrait” или “landscape.”

Для более подробной информации смотри "Определение печатной области (при использовании класса PrintJob)" в Использовании Flash.

После того, как пользователь кликнет OK в диалоговом окне Print, Flash Player запускает спулер и отправляет ему запрос. Далее Вам необходимо программно произвести некие действия, влияющие на процесс печати, например, метод PrintJob.addPage() добавляет страницы в список спулера. Для определения формата отпечатка можно использовать доступные только для чтения свойства pageHeight, pageWidth, paperHeight, paperWidth и opientation.

Т.к. пользователь увидит оповещение, подобное “Printing page 1”, сразу после нажатия на OK, следует сразу же вызвать PrintJob.addPage() и PrintJob.send(), чтобы начать печать.

Если данным методом возвращается false (например, если пользователь отменил печать), все последующие вызовы PrintJob.addPage() не сработают. Однако, если предыдущие вызовы PrintJob.addPage() прошли удачно, вызов метода PrintJob.send() отправит страницы, занесенные в список спулера, на печать.

var my_pj:PrintJob = new PrintJob();
var myResult:Boolean = my_pj.start();
  if(myResult) {
    // Здесь должны быть addPage() и send()   
  }
delete my_pj;

Пример

В следующем примере показано, как может быть использовано свойство orientation:

// Создаем PrintJob
var my_pj:PrintJob = new PrintJob();

// Отображаем диалоговое окно
if (my_pj.start()) {
  // Проверяем, удачно ли прошел вызов addPage
  var pageAdded:Boolean = false;

  // Проверяем настройки ориентации страницы
  // и соответственно подбираем печатную зону
  if (my_pj.orientation == "portrait") {
    // В данном случае размеры для изображения 8.5" x 11" с книжной ориентацией
    pageAdded = my_pj.addPage(this,{xMin:0,xMax:600,yMin:0,yMax:800});
  }
  else {
    // my_pj.orientation is "landscape".
    // А теперь размеры для 11" x 8.5"
    // в альбомном варианте.
    pageAdded = my_pj.addPage(this,{xMin:0,xMax:750,yMin:0,yMax:600});
  }

  // Отправляем страницы на печать
  if (pageAdded) {
    my_pj.send(); 
  }
}

// clean up
delete my_pj;

См. также

PrintJob.addPage(), PrintJob.send()

Смотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление